***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Sep 20, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4464AP-AU   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = 2.4		 kp = 85.5	)
.model  dds   d(
+   is = 4.176e-12	  n = 1.028		   rs = 4.216e-3
+   eg = 1.106	     trs1 = 1.618e-2 )
.model  dbody d(
+   is = 4.376e-12	  n = 1.038		   rs = 4.216e-3
+  cjo = 3.647e-10	  m = 5.249e-1	   vj = 3.905e-1
+   bv = 66			ibv = 250e-6	 tbv1 = 1.375e-3		tbv2 = -1.995e-6
+   tt = 25n)
.model  inter  nmos(
+  vto = 0			 kp = 10		level = 1)
.model  dgd   d(
+  cjo = 4.767e-10	  m = 4.549e-1	   vj = 3.905e-1)
.param
+  cgs = 2.014e-9	cgd = 4.383e-10
+   rd = 8.260e-3		 ra = 1.000e-3	  trd = 1.185e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}    ic = 0
egv	 2t   3   table   {v(1t, S)} 
+((0.00 , 0.00 ),
+ (0.50 , 0.50 ),
+ (1.00 , 1.00 ),
+ (1.50 , 1.50 ),
+ (2.00 , 2.00 ),
+ (2.50 , 2.45 ),
+ (3.00 , 2.78 ),
+ (3.50 , 3.35 ),
+ (4.00 , 4.00 ),
+ (4.50 , 4.45 ),
+ (5.00 , 4.80 ),
+ (6.00 , 5.20 ),
+ (8.00 , 5.60 ),
+ (10.0 , 5.85 ),
+ (20.0 , 5.90 ),
+ (22.0 , 5.90 ))
egt	  1  2t   value = {5.087e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4  1t   2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
